Files
Aws-Terraform/modules/network_public/locals.tf
T

122 lines
4.1 KiB
Terraform

locals {
vpc = var.protect_from_destroy ? aws_vpc.protected[0] : aws_vpc.unprotected[0]
subnet_ids = merge(
{ for key, subnet in aws_subnet.protected : key => subnet.id },
{ for key, subnet in aws_subnet.unprotected : key => subnet.id },
)
internet_gateway_id = var.protect_from_destroy ? aws_internet_gateway.protected[0].id : aws_internet_gateway.unprotected[0].id
route_table_ids = {
dmz = var.protect_from_destroy ? aws_default_route_table.protected[0].id : aws_default_route_table.unprotected[0].id
intra = var.protect_from_destroy ? aws_route_table.protected[0].id : aws_route_table.unprotected[0].id
}
routes = {
dmz_private_a = {
route_table_key = "dmz"
destination = var.route_destinations.private_network_a
gateway_id = null
network_interface_id = var.vyos_network_interface_id
}
dmz_private_b = {
route_table_key = "dmz"
destination = var.route_destinations.private_network_b
gateway_id = null
network_interface_id = var.vyos_network_interface_id
}
dmz_internet = {
route_table_key = "dmz"
destination = var.route_destinations.default_ipv4
gateway_id = local.internet_gateway_id
network_interface_id = null
}
intra_private_a = {
route_table_key = "intra"
destination = var.route_destinations.private_network_a
gateway_id = null
network_interface_id = var.vyos_network_interface_id
}
intra_private_b = {
route_table_key = "intra"
destination = var.route_destinations.private_network_b
gateway_id = null
network_interface_id = var.vyos_network_interface_id
}
intra_default = {
route_table_key = "intra"
destination = var.route_destinations.default_ipv4
gateway_id = null
network_interface_id = var.vyos_network_interface_id
}
}
route_table_associations = {
dmz = {
subnet_key = "dmz"
route_table_key = "dmz"
}
intra_a = {
subnet_key = "intra_a"
route_table_key = "intra"
}
intra_d = {
subnet_key = "intra_d"
route_table_key = "intra"
}
}
web_egress_homelab_cidrs = {
private_network_a = var.route_destinations.private_network_a
private_network_b = var.route_destinations.private_network_b
}
web_egress_rules = merge(
{
for pair in setproduct(keys(local.web_egress_homelab_cidrs), var.web_egress_policy.homelab_tcp_ports) :
"${pair[0]}_tcp_${pair[1]}" => {
description = "Allow TCP ${pair[1]} to homelab ${replace(pair[0], "_", " ")} via VyOS"
ip_protocol = "tcp"
from_port = pair[1]
to_port = pair[1]
cidr_ipv4 = local.web_egress_homelab_cidrs[pair[0]]
}
},
{
for pair in setproduct(keys(local.web_egress_homelab_cidrs), var.web_egress_policy.homelab_udp_ports) :
"${pair[0]}_udp_${pair[1]}" => {
description = "Allow UDP ${pair[1]} to homelab ${replace(pair[0], "_", " ")} via VyOS"
ip_protocol = "udp"
from_port = pair[1]
to_port = pair[1]
cidr_ipv4 = local.web_egress_homelab_cidrs[pair[0]]
}
},
{
for port in var.web_egress_policy.public_tcp_ports :
"public_tcp_${port}" => {
description = "Allow TCP ${port} to any IPv4 destination"
ip_protocol = "tcp"
from_port = port
to_port = port
cidr_ipv4 = "0.0.0.0/0"
}
},
{
for key, rule in var.web_egress_service_rules :
"service_${key}" => {
description = rule.description
ip_protocol = rule.ip_protocol
from_port = rule.port
to_port = rule.port
cidr_ipv4 = rule.cidr_ipv4
}
},
)
ssh_security_group_name = coalesce(var.ssh_security_group.name, "${var.name_prefix}-ssh-enabled")
web_instance_name = coalesce(var.web_instance.name, "${var.name_prefix}-web")
key_pair_name = coalesce(var.key_pair.name, "${var.name_prefix}-key")
}