Files
2026-11-14 16:58:52 +09:00

70 lines
1.6 KiB
Terraform

resource "aws_iam_role" "flow_logs" {
name = local.flow_logs_role_name
path = "/service-role/"
max_session_duration = 3600
assume_role_policy = jsonencode({
Version = "2012-10-17"
Statement = [{
Effect = "Allow"
Principal = {
Service = "vpc-flow-logs.amazonaws.com"
}
Action = "sts:AssumeRole"
Condition = {
StringEquals = {
"aws:SourceAccount" = var.account_id
}
ArnLike = {
"aws:SourceArn" = "arn:aws:ec2:${var.region}:${var.account_id}:vpc-flow-log/*"
}
}
}]
})
lifecycle {
prevent_destroy = true
}
}
resource "aws_iam_policy" "flow_logs" {
name = local.flow_logs_policy_name
path = "/service-role/"
policy = jsonencode({
Version = "2012-10-17"
Statement = [
{
Effect = "Allow"
Action = [
"logs:CreateLogStream",
"logs:PutLogEvents",
]
Resource = "arn:aws:logs:${var.region}:${var.account_id}:log-group:*:log-stream:*"
},
{
Effect = "Allow"
Action = [
"logs:DescribeLogStreams",
"logs:CreateLogGroup",
]
Resource = "arn:aws:logs:${var.region}:${var.account_id}:log-group:*"
},
{
Effect = "Allow"
Action = "logs:DescribeLogGroups"
Resource = "*"
},
]
})
lifecycle {
prevent_destroy = true
}
}
resource "aws_iam_role_policy_attachment" "flow_logs" {
role = aws_iam_role.flow_logs.name
policy_arn = aws_iam_policy.flow_logs.arn
}