Files
Aws-Terraform/modules/audit_logging_encryption/s3.tf
T

213 lines
4.6 KiB
Terraform

resource "aws_s3_bucket" "protected" {
for_each = var.protect_from_destroy ? local.buckets : {}
bucket = each.value
force_destroy = false
lifecycle {
prevent_destroy = true
}
}
resource "aws_s3_bucket" "unprotected" {
for_each = var.protect_from_destroy ? {} : local.buckets
bucket = each.value
force_destroy = var.force_destroy_unprotected_buckets
}
resource "aws_s3_bucket_versioning" "this" {
for_each = local.buckets
bucket = local.bucket_ids[each.key]
versioning_configuration {
status = "Enabled"
}
}
resource "aws_s3_bucket_server_side_encryption_configuration" "this" {
for_each = local.buckets
bucket = local.bucket_ids[each.key]
rule {
apply_server_side_encryption_by_default {
sse_algorithm = "AES256"
}
bucket_key_enabled = each.key != "cloudtrail"
blocked_encryption_types = ["SSE-C"]
}
}
resource "aws_s3_bucket_public_access_block" "this" {
for_each = local.buckets
bucket = local.bucket_ids[each.key]
block_public_acls = true
block_public_policy = true
ignore_public_acls = true
restrict_public_buckets = true
}
resource "aws_s3_bucket_ownership_controls" "this" {
for_each = local.buckets
bucket = local.bucket_ids[each.key]
rule {
object_ownership = "BucketOwnerEnforced"
}
}
resource "aws_s3_bucket_policy" "this" {
for_each = local.buckets
bucket = local.bucket_ids[each.key]
policy = local.bucket_policies[each.key]
}
resource "aws_s3_bucket_lifecycle_configuration" "this" {
for_each = local.lifecycle_rules
bucket = local.bucket_ids[each.key]
transition_default_minimum_object_size = "all_storage_classes_128K"
rule {
id = each.value.id
status = "Enabled"
expiration {
days = each.value.expiration_days
}
noncurrent_version_expiration {
noncurrent_days = each.value.noncurrent_expiration_days
}
}
rule {
id = "DeleteExpiredObjectDeleteMarkers"
status = "Enabled"
expiration {
expired_object_delete_marker = true
}
}
depends_on = [aws_s3_bucket_versioning.this]
}
resource "aws_s3_bucket" "access_logs_protected" {
count = var.protect_from_destroy ? 1 : 0
bucket = local.access_log_bucket_name
bucket_namespace = var.access_log_bucket_namespace
force_destroy = false
lifecycle {
prevent_destroy = true
}
}
resource "aws_s3_bucket" "access_logs_unprotected" {
count = var.protect_from_destroy ? 0 : 1
bucket = local.access_log_bucket_name
bucket_namespace = var.access_log_bucket_namespace
force_destroy = var.force_destroy_unprotected_buckets
}
resource "aws_s3_bucket_versioning" "access_logs" {
bucket = local.access_log_bucket_id
versioning_configuration {
status = "Enabled"
}
}
resource "aws_s3_bucket_server_side_encryption_configuration" "access_logs" {
bucket = local.access_log_bucket_id
rule {
apply_server_side_encryption_by_default {
sse_algorithm = "AES256"
}
bucket_key_enabled = false
blocked_encryption_types = ["SSE-C"]
}
}
resource "aws_s3_bucket_public_access_block" "access_logs" {
bucket = local.access_log_bucket_id
block_public_acls = true
block_public_policy = true
ignore_public_acls = true
restrict_public_buckets = true
}
resource "aws_s3_bucket_ownership_controls" "access_logs" {
bucket = local.access_log_bucket_id
rule {
object_ownership = "BucketOwnerEnforced"
}
}
resource "aws_s3_bucket_policy" "access_logs" {
bucket = local.access_log_bucket_id
policy = local.access_log_bucket_policy
}
resource "aws_s3_bucket_lifecycle_configuration" "access_logs" {
bucket = local.access_log_bucket_id
transition_default_minimum_object_size = "all_storage_classes_128K"
rule {
id = "DeleteAfter90Days"
status = "Enabled"
expiration {
days = local.access_log_retention_days
}
noncurrent_version_expiration {
noncurrent_days = local.access_log_retention_days
}
}
rule {
id = "DeleteExpiredObjectDeleteMarkers"
status = "Enabled"
expiration {
expired_object_delete_marker = true
}
}
depends_on = [aws_s3_bucket_versioning.access_logs]
}
resource "aws_s3_bucket_logging" "this" {
for_each = local.buckets
bucket = local.bucket_ids[each.key]
target_bucket = local.access_log_bucket_id
target_prefix = local.access_log_prefixes[each.key]
target_object_key_format {
partitioned_prefix {
partition_date_source = "EventTime"
}
}
depends_on = [
aws_s3_bucket_ownership_controls.access_logs,
aws_s3_bucket_policy.access_logs,
]
}